<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Term::Table::LineBreak;
use strict;
use warnings;

our $VERSION = '0.018';

use Carp qw/croak/;
use Scalar::Util qw/blessed/;
use Term::Table::Util qw/uni_length/;

use Term::Table::HashBase qw/string gcstring _len _parts idx/;

sub init {
    my $self = shift;

    croak "string is a required attribute"
        unless defined $self-&gt;{+STRING};
}

sub columns { uni_length($_[0]-&gt;{+STRING}) }

sub break {
    my $self = shift;
    my ($len) = @_;

    $self-&gt;{+_LEN} = $len;

    $self-&gt;{+IDX} = 0;
    my $str = $self-&gt;{+STRING} . ""; # Force stringification

    my @parts;
    my @chars = split //, $str;
    while (@chars) {
        my $size = 0;
        my $part = '';
        until ($size == $len) {
            my $char = shift @chars;
            $char = '' unless defined $char;

            my $l = uni_length("$char");
            last unless $l;

            last if $char eq "\n";

            if ($size + $l &gt; $len) {
                unshift @chars =&gt; $char;
                last;
            }

            $size += $l;
            $part .= $char;
        }

        # If we stopped just before a newline, grab it
        shift @chars if $size == $len &amp;&amp; @chars &amp;&amp; $chars[0] eq "\n";

        until ($size == $len) {
            $part .= ' ';
            $size += 1;
        }
        push @parts =&gt; $part;
    }

    $self-&gt;{+_PARTS} = \@parts;
}

sub next {
    my $self = shift;

    if (@_) {
        my ($len) = @_;
        $self-&gt;break($len) if !$self-&gt;{+_LEN} || $self-&gt;{+_LEN} != $len;
    }
    else {
        croak "String has not yet been broken"
            unless $self-&gt;{+_PARTS};
    }

    my $idx   = $self-&gt;{+IDX}++;
    my $parts = $self-&gt;{+_PARTS};

    return undef if $idx &gt;= @$parts;
    return $parts-&gt;[$idx];
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Term::Table::LineBreak - Break up lines for use in tables.

=head1 DESCRIPTION

This is meant for internal use. This package takes long lines of text and
splits them so that they fit in table rows.

=head1 SYNOPSIS

    use Term::Table::LineBreak;

    my $lb = Term::Table::LineBreak-&gt;new(string =&gt; $STRING);

    $lb-&gt;break($SIZE);
    while (my $part = $lb-&gt;next) {
        ...
    }

=head1 SOURCE

The source code repository for Term-Table can be found at
F&lt;http://github.com/exodist/Term-Table/&gt;.

=head1 MAINTAINERS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 AUTHORS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 COPYRIGHT

Copyright 2016 Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;.

This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

See F&lt;http://dev.perl.org/licenses/&gt;

=cut
</pre></body></html>