<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Test2::Compare::Delta;
use strict;
use warnings;

our $VERSION = '0.000162';

use Test2::Util::HashBase qw{verified id got chk children dne exception note};

use Test2::EventFacet::Info::Table;

use Test2::Util::Table();
use Test2::API qw/context/;

use Test2::Util::Ref qw/render_ref rtype/;
use Carp qw/croak/;

# 'CHECK' constant would not work, but I like exposing 'check()' to people
# using this class.
BEGIN {
    no warnings 'once';
    *check = \&amp;chk;
    *set_check = \&amp;set_chk;
}

my @COLUMN_ORDER = qw/PATH GLNs GOT OP CHECK CLNs/;
my %COLUMNS = (
    GOT   =&gt; {name =&gt; 'GOT',   value =&gt; sub { $_[0]-&gt;render_got },   no_collapse =&gt; 1},
    CHECK =&gt; {name =&gt; 'CHECK', value =&gt; sub { $_[0]-&gt;render_check }, no_collapse =&gt; 1},
    OP    =&gt; {name =&gt; 'OP',    value =&gt; sub { $_[0]-&gt;table_op }                      },
    PATH  =&gt; {name =&gt; 'PATH',  value =&gt; sub { $_[1] }                                },

    'GLNs' =&gt; {name =&gt; 'GLNs', alias =&gt; 'LNs', value =&gt; sub { $_[0]-&gt;table_got_lines }  },
    'CLNs' =&gt; {name =&gt; 'CLNs', alias =&gt; 'LNs', value =&gt; sub { $_[0]-&gt;table_check_lines }},
);
{
    my $i = 0;
    $COLUMNS{$_}-&gt;{id} = $i++ for @COLUMN_ORDER;
}

sub remove_column {
    my $class = shift;
    my $header = shift;
    @COLUMN_ORDER = grep { $_ ne $header } @COLUMN_ORDER;
    delete $COLUMNS{$header} ? 1 : 0;
}

sub add_column {
    my $class = shift;
    my $name = shift;

    croak "Column name is required"
        unless $name;

    croak "Column '$name' is already defined"
        if $COLUMNS{$name};

    my %params;
    if (@_ == 1) {
        %params = (value =&gt; @_, name =&gt; $name);
    }
    else {
        %params = (@_, name =&gt; $name);
    }

    my $value = $params{value};

    croak "You must specify a 'value' callback"
        unless $value;

    croak "'value' callback must be a CODE reference"
        unless rtype($value) eq 'CODE';

    if ($params{prefix}) {
        unshift @COLUMN_ORDER =&gt; $name;
    }
    else {
        push @COLUMN_ORDER =&gt; $name;
    }

    $COLUMNS{$name} = \%params;
}

sub set_column_alias {
    my ($class, $name, $alias) = @_;

    croak "Tried to alias a non-existent column"
        unless exists $COLUMNS{$name};

    croak "Missing alias" unless defined $alias;

    $COLUMNS{$name}-&gt;{alias} = $alias;
}

sub init {
    my $self = shift;

    croak "Cannot specify both 'check' and 'chk' as arguments"
        if exists($self-&gt;{check}) &amp;&amp; exists($self-&gt;{+CHK});

    # Allow 'check' as an argument
    $self-&gt;{+CHK} ||= delete $self-&gt;{check}
        if exists $self-&gt;{check};
}

sub render_got {
    my $self = shift;

    my $exp = $self-&gt;{+EXCEPTION};
    if ($exp) {
        chomp($exp = "$exp");
        $exp =~ s/\n.*$//g;
        return "&lt;EXCEPTION: $exp&gt;";
    }

    my $dne = $self-&gt;{+DNE};
    return '&lt;DOES NOT EXIST&gt;' if $dne &amp;&amp; $dne eq 'got';

    my $got = $self-&gt;{+GOT};
    return '&lt;UNDEF&gt;' unless defined $got;

    my $check = $self-&gt;{+CHK};
    my $stringify = defined( $check ) &amp;&amp; $check-&gt;stringify_got;

    return render_ref($got) if ref $got &amp;&amp; !$stringify;

    return "$got";
}

sub render_check {
    my $self = shift;

    my $dne = $self-&gt;{+DNE};
    return '&lt;DOES NOT EXIST&gt;' if $dne &amp;&amp; $dne eq 'check';

    my $check = $self-&gt;{+CHK};
    return '&lt;UNDEF&gt;' unless defined $check;

    return $check-&gt;render;
}

sub _full_id {
    my ($type, $id) = @_;
    return "&lt;$id&gt;" if !$type || $type eq 'META';
    return $id     if $type eq 'SCALAR';
    return "{$id}" if $type eq 'HASH';
    return "{$id} &lt;KEY&gt;" if $type eq 'HASHKEY';
    return "[$id]" if $type eq 'ARRAY';
    return "$id()" if $type eq 'METHOD';
    return "$id" if $type eq 'DEREF';
    return "&lt;$id&gt;";
}

sub _arrow_id {
    my ($path, $type) = @_;
    return '' unless $path;

    return ' ' if !$type || $type eq 'META';    # Meta gets a space, not an arrow

    return '-&gt;' if $type eq 'METHOD';           # Method always needs an arrow
    return '-&gt;' if $type eq 'SCALAR';           # Scalar always needs an arrow
    return '-&gt;' if $type eq 'DEREF';            # deref always needs arrow
    return '-&gt;' if $path =~ m/(&gt;|\(\))$/;       # Need an arrow after meta, or after a method
    return '-&gt;' if $path eq '$VAR';             # Need an arrow after the initial ref

    # Hash and array need an arrow unless they follow another hash/array
    return '-&gt;' if $type =~ m/^(HASH|ARRAY)$/ &amp;&amp; $path !~ m/(\]|\})$/;

    # No arrow needed
    return '';
}

sub _join_id {
    my ($path, $parts) = @_;
    my ($type, $key) = @$parts;

    my $id   = _full_id($type, $key);
    my $join = _arrow_id($path, $type);

    return "${path}${join}${id}";
}

sub should_show {
    my $self = shift;
    return 1 unless $self-&gt;verified;
    defined( my $check = $self-&gt;check ) || return 0;
    return 0 unless $check-&gt;lines;
    my $file = $check-&gt;file || return 0;

    my $ctx = context();
    my $cfile = $ctx-&gt;trace-&gt;file;
    $ctx-&gt;release;
    return 0 unless $file eq $cfile;

    return 1;
}

sub filter_visible {
    my $self = shift;

    my @deltas;
    my @queue = (['', $self]);

    while (my $set = shift @queue) {
        my ($path, $delta) = @$set;

        push @deltas =&gt; [$path, $delta] if $delta-&gt;should_show;

        my $children = $delta-&gt;children || next;
        next unless @$children;

        my @new;
        for my $child (@$children) {
            my $cpath = _join_id($path, $child-&gt;id);
            push @new =&gt; [$cpath, $child];
        }
        unshift @queue =&gt; @new;
    }

    return \@deltas;
}

sub table_header { [map {$COLUMNS{$_}-&gt;{alias} || $_} @COLUMN_ORDER] }

sub table_op {
    my $self = shift;

    defined( my $check = $self-&gt;{+CHK} ) || return '!exists';

    return $check-&gt;operator($self-&gt;{+GOT})
        unless $self-&gt;{+DNE} &amp;&amp; $self-&gt;{+DNE} eq 'got';

    return $check-&gt;operator();
}

sub table_check_lines {
    my $self = shift;

    defined( my $check = $self-&gt;{+CHK} ) || return '';
    my $lines = $check-&gt;lines || return '';

    return '' unless @$lines;

    return join ', ' =&gt; @$lines;
}

sub table_got_lines {
    my $self = shift;

    defined( my $check = $self-&gt;{+CHK} ) || return '';
    return '' if $self-&gt;{+DNE} &amp;&amp; $self-&gt;{+DNE} eq 'got';

    my @lines = $check-&gt;got_lines($self-&gt;{+GOT});
    return '' unless @lines;

    return join ', ' =&gt; @lines;
}

sub table_rows {
    my $self = shift;

    my $deltas = $self-&gt;filter_visible;

    my @rows;
    for my $set (@$deltas) {
        my ($id, $d) = @$set;

        my @row;
        for my $col (@COLUMN_ORDER) {
            my $spec = $COLUMNS{$col};
            my $val = $spec-&gt;{value}-&gt;($d, $id);
            $val = '' unless defined $val;
            push @row =&gt; $val;
        }

        push @rows =&gt; \@row;
    }

    return \@rows;
}

sub table {
    my $self = shift;

    my @diag;
    my $header = $self-&gt;table_header;
    my $rows   = $self-&gt;table_rows;

    my $render_rows = [@$rows];
    my $max = exists $ENV{TS_MAX_DELTA} ? $ENV{TS_MAX_DELTA} : 25;
    if ($max &amp;&amp; @$render_rows &gt; $max) {
        @$render_rows = map { [@$_] } @{$render_rows}[0 .. ($max - 1)];
        @diag = (
            "************************************************************",
            sprintf("* Stopped after %-42.42s *", "$max differences."),
            "* Set the TS_MAX_DELTA environment var to raise the limit. *",
            "* Set it to 0 for no limit.                                *",
            "************************************************************",
        );
    }

    my @dne;
    for my $row (@$render_rows) {
        my $got = $row-&gt;[$COLUMNS{GOT}-&gt;{id}]   || '';
        my $chk = $row-&gt;[$COLUMNS{CHECK}-&gt;{id}] || '';
        if ($got eq '&lt;DOES NOT EXIST&gt;') {
            push @dne =&gt; "$row-&gt;[$COLUMNS{PATH}-&gt;{id}]:   DOES NOT EXIST";
        }
        elsif ($chk eq '&lt;DOES NOT EXIST&gt;') {
            push @dne =&gt; "$row-&gt;[$COLUMNS{PATH}-&gt;{id}]: SHOULD NOT EXIST";
        }
    }

    if (@dne) {
        unshift @dne =&gt; '==== Summary of missing/extra items ====';
        push    @dne =&gt; '== end summary of missing/extra items ==';
    }

    my $table_args = {
        header      =&gt; $header,
        collapse    =&gt; 1,
        sanitize    =&gt; 1,
        mark_tail   =&gt; 1,
        no_collapse =&gt; [grep { $COLUMNS{$COLUMN_ORDER[$_]}-&gt;{no_collapse} } 0 .. $#COLUMN_ORDER],
    };

    my $render = join "\n" =&gt; (
        Test2::Util::Table::table(%$table_args, rows =&gt; $render_rows),
        @dne,
        @diag,
    );

    my $table = Test2::EventFacet::Info::Table-&gt;new(
        %$table_args,
        rows      =&gt; $rows,
        as_string =&gt; $render,
    );

    return $table;
}

sub diag { shift-&gt;table }

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Test2::Compare::Delta - Representation of differences between nested data
structures.

=head1 DESCRIPTION

This is used by L&lt;Test2::Compare&gt;. When data structures are compared a
delta will be returned. Deltas are a tree data structure that represent all the
differences between two other data structures.

=head1 METHODS

=head2 CLASS METHODS

=over 4

=item $class-&gt;add_column($NAME =&gt; sub { ... })

=item $class-&gt;add_column($NAME, %PARAMS)

This can be used to add columns to the table that it produced when a comparison
fails. The first argument should always be the column name, which must be
unique.

The first form simply takes a coderef that produces the value that should be
displayed in the column for any given delta. The arguments passed into the sub
are the delta, and the row ID.

    Test2::Compare::Delta-&gt;add_column(
        Foo =&gt; sub {
            my ($delta, $id) = @_;
            return $delta-&gt;... ? 'foo' : 'bar'
        },
    );

The second form allows you some extra options. The C&lt;'value'&gt; key is required,
and must be a coderef. All other keys are optional.

    Test2::Compare::Delta-&gt;add_column(
        'Foo',    # column name
        value =&gt; sub { ... },    # how to get the cell value
        alias       =&gt; 'FOO',    # Display name (used in table header)
        no_collapse =&gt; $bool,    # Show column even if it has no values?
    );

=item $bool = $class-&gt;remove_column($NAME)

This will remove the specified column. This will return true if the column
existed and was removed. This will return false if the column did not exist. No
exceptions are thrown. If a missing column is a problem then you need to check
the return yourself.

=item $class-&gt;set_column_alias($NAME, $ALIAS)

This can be used to change the table header, overriding the default column
names with new ones.

=back

=head2 ATTRIBUTES

=over 4

=item $bool = $delta-&gt;verified

=item $delta-&gt;set_verified($bool)

This will be true if the delta itself matched, if the delta matched then the
problem is in the delta's children, not the delta itself.

=item $aref = $delta-&gt;id

=item $delta-&gt;set_id([$type, $name])

ID for the delta, used to produce the path into the data structure. An
example is C&lt;&lt; ['HASH' =&gt; 'foo'] &gt;&gt; which means the delta is in the path
C&lt;&lt; ...-&gt;{'foo'} &gt;&gt;. Valid types are C&lt;HASH&gt;, C&lt;ARRAY&gt;, C&lt;SCALAR&gt;, C&lt;META&gt;, and
C&lt;METHOD&gt;.

=item $val = $delta-&gt;got

=item $delta-&gt;set_got($val)

Deltas are produced by comparing a received data structure 'got' against a
check data structure 'check'. The 'got' attribute contains the value that was
received for comparison.

=item $check = $delta-&gt;chk

=item $check = $delta-&gt;check

=item $delta-&gt;set_chk($check)

=item $delta-&gt;set_check($check)

Deltas are produced by comparing a received data structure 'got' against a
check data structure 'check'. The 'check' attribute contains the value that was
expected in the comparison.

C&lt;check&gt; and C&lt;chk&gt; are aliases for the same attribute.

=item $aref = $delta-&gt;children

=item $delta-&gt;set_children([$delta1, $delta2, ...])

A Delta may have child deltas. If it does then this is an arrayref with those
children.

=item $dne = $delta-&gt;dne

=item $delta-&gt;set_dne($dne)

Sometimes a comparison results in one side or the other not existing at all, in
which case this is set to the name of the attribute that does not exist. This
can be set to 'got' or 'check'.

=item $e = $delta-&gt;exception

=item $delta-&gt;set_exception($e)

This will be set to the exception in cases where the comparison failed due to
an exception being thrown.

=back

=head2 OTHER

=over 4

=item $string = $delta-&gt;render_got

Renders the string that should be used in a table to represent the received
value in a comparison.

=item $string = $delta-&gt;render_check

Renders the string that should be used in a table to represent the expected
value in a comparison.

=item $bool = $delta-&gt;should_show

This will return true if the delta should be shown in the table. This is
normally true for any unverified delta. This will also be true for deltas that
contain extra useful debug information.

=item $aref = $delta-&gt;filter_visible

This will produce an arrayref of C&lt;&lt; [ $path =&gt; $delta ] &gt;&gt; for all deltas that
should be displayed in the table.

=item $aref = $delta-&gt;table_header

This returns an array ref of the headers for the table.

=item $string = $delta-&gt;table_op

This returns the operator that should be shown in the table.

=item $string = $delta-&gt;table_check_lines

This returns the defined lines (extra debug info) that should be displayed.

=item $string = $delta-&gt;table_got_lines

This returns the generated lines (extra debug info) that should be displayed.

=item $aref = $delta-&gt;table_rows

This returns an arrayref of table rows, each row is itself an arrayref.

=item @table_lines = $delta-&gt;table

Returns all the lines of the table that should be displayed.

=back

=head1 SOURCE

The source code repository for Test2-Suite can be found at
F&lt;https://github.com/Test-More/Test2-Suite/&gt;.

=head1 MAINTAINERS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 AUTHORS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 COPYRIGHT

Copyright 2018 Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;.

This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

See F&lt;http://dev.perl.org/licenses/&gt;

=cut
</pre></body></html>