<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Test2::Compare::Hash;
use strict;
use warnings;

use base 'Test2::Compare::Base';

our $VERSION = '0.000162';

use Test2::Util::HashBase qw/inref meta ending items order for_each_key for_each_val/;

use Carp qw/croak confess/;
use Scalar::Util qw/reftype/;

sub init {
    my $self = shift;

    if( defined( my $ref = $self-&gt;{+INREF} ) ) {
        croak "Cannot specify both 'inref' and 'items'" if $self-&gt;{+ITEMS};
        croak "Cannot specify both 'inref' and 'order'" if $self-&gt;{+ORDER};
        $self-&gt;{+ITEMS} = {%$ref};
        $self-&gt;{+ORDER} = [sort keys %$ref];
    }
    else {
        # Clone the ref to be safe
        $self-&gt;{+ITEMS} = $self-&gt;{+ITEMS} ? {%{$self-&gt;{+ITEMS}}} : {};
        if ($self-&gt;{+ORDER}) {
            my @all = keys %{$self-&gt;{+ITEMS}};
            my %have = map { $_ =&gt; 1 } @{$self-&gt;{+ORDER}};
            my @missing = grep { !$have{$_} } @all;
            croak "Keys are missing from the 'order' array: " . join(', ', sort @missing)
                if @missing;
        }
        else {
            $self-&gt;{+ORDER} = [sort keys %{$self-&gt;{+ITEMS}}];
        }
    }

    $self-&gt;{+FOR_EACH_KEY} ||= [];
    $self-&gt;{+FOR_EACH_VAL} ||= [];

    $self-&gt;SUPER::init();
}

sub name { '&lt;HASH&gt;' }

sub meta_class  { 'Test2::Compare::Meta' }

sub verify {
    my $self = shift;
    my %params = @_;
    my ($got, $exists) = @params{qw/got exists/};

    return 0 unless $exists;
    return 0 unless defined $got;
    return 0 unless ref($got);
    return 0 unless reftype($got) eq 'HASH';
    return 1;
}

sub add_prop {
    my $self = shift;
    $self-&gt;{+META} = $self-&gt;meta_class-&gt;new unless defined $self-&gt;{+META};
    $self-&gt;{+META}-&gt;add_prop(@_);
}

sub add_field {
    my $self = shift;
    my ($name, $check) = @_;

    croak "field name is required"
        unless defined $name;

    croak "field '$name' has already been specified"
        if exists $self-&gt;{+ITEMS}-&gt;{$name};

    push @{$self-&gt;{+ORDER}} =&gt; $name;
    $self-&gt;{+ITEMS}-&gt;{$name} = $check;
}

sub add_for_each_key {
    my $self = shift;
    push @{$self-&gt;{+FOR_EACH_KEY}} =&gt; @_;
}

sub add_for_each_val {
    my $self = shift;
    push @{$self-&gt;{+FOR_EACH_VAL}} =&gt; @_;
}

sub deltas {
    my $self = shift;
    my %params = @_;
    my ($got, $convert, $seen) = @params{qw/got convert seen/};

    my @deltas;
    my $items = $self-&gt;{+ITEMS};
    my $each_key = $self-&gt;{+FOR_EACH_KEY};
    my $each_val = $self-&gt;{+FOR_EACH_VAL};

    # Make a copy that we can munge as needed.
    my %fields = %$got;

    my $meta     = $self-&gt;{+META};
    push @deltas =&gt; $meta-&gt;deltas(%params) if defined $meta;

    for my $key (@{$self-&gt;{+ORDER}}) {
        my $check  = $convert-&gt;($items-&gt;{$key});
        my $exists = exists $fields{$key};
        my $val    = delete $fields{$key};

        if ($exists) {
            for my $kcheck (@$each_key) {
                $kcheck = $convert-&gt;($kcheck);

                push @deltas =&gt; $kcheck-&gt;run(
                    id      =&gt; [HASHKEY =&gt; $key],
                    convert =&gt; $convert,
                    seen    =&gt; $seen,
                    exists  =&gt; $exists,
                    got     =&gt; $key,
                );
            }

            for my $vcheck (@$each_val) {
                $vcheck = $convert-&gt;($vcheck);

                push @deltas =&gt; $vcheck-&gt;run(
                    id      =&gt; [HASH =&gt; $key],
                    convert =&gt; $convert,
                    seen    =&gt; $seen,
                    exists  =&gt; $exists,
                    got     =&gt; $val,
                );
            }
        }

        push @deltas =&gt; $check-&gt;run(
            id      =&gt; [HASH =&gt; $key],
            convert =&gt; $convert,
            seen    =&gt; $seen,
            exists  =&gt; $exists,
            $exists ? (got =&gt; $val) : (),
        );
    }

    if (keys %fields) {
        for my $key (sort keys %fields) {
            my $val = $fields{$key};

            for my $kcheck (@$each_key) {
                $kcheck = $convert-&gt;($kcheck);

                push @deltas =&gt; $kcheck-&gt;run(
                    id      =&gt; [HASHKEY =&gt; $key],
                    convert =&gt; $convert,
                    seen    =&gt; $seen,
                    got     =&gt; $key,
                    exists  =&gt; 1,
                );
            }

            for my $vcheck (@$each_val) {
                $vcheck = $convert-&gt;($vcheck);

                push @deltas =&gt; $vcheck-&gt;run(
                    id      =&gt; [HASH =&gt; $key],
                    convert =&gt; $convert,
                    seen    =&gt; $seen,
                    got     =&gt; $val,
                    exists  =&gt; 1,
                );
            }

            # if items are left over, and ending is true, we have a problem!
            if ($self-&gt;{+ENDING}) {
                push @deltas =&gt; $self-&gt;delta_class-&gt;new(
                    dne      =&gt; 'check',
                    verified =&gt; undef,
                    id       =&gt; [HASH =&gt; $key],
                    got      =&gt; $val,
                    check    =&gt; undef,

                    $self-&gt;{+ENDING} eq 'implicit' ? (note =&gt; 'implicit end') : (),
                );
            }
        }
    }

    return @deltas;
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Test2::Compare::Hash - Representation of a hash in a deep comparison.

=head1 DESCRIPTION

In deep comparisons this class is used to represent a hash.

=head1 SOURCE

The source code repository for Test2-Suite can be found at
F&lt;https://github.com/Test-More/Test2-Suite/&gt;.

=head1 MAINTAINERS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 AUTHORS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 COPYRIGHT

Copyright 2018 Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;.

This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

See F&lt;http://dev.perl.org/licenses/&gt;

=cut
</pre></body></html>