<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package LWP::Simple;

use strict;

our $VERSION = '6.77';

require Exporter;

our @EXPORT = qw(get head getprint getstore mirror);
our @EXPORT_OK = qw($ua);

# I really hate this.  It was a bad idea to do it in the first place.
# Wonder how to get rid of it???  (It even makes LWP::Simple 7% slower
# for trivial tests)
use HTTP::Status;
push(@EXPORT, @HTTP::Status::EXPORT);

sub import
{
    my $pkg = shift;
    my $callpkg = caller;
    Exporter::export($pkg, $callpkg, @_);
}

use LWP::UserAgent ();
use HTTP::Date ();

our $ua = LWP::UserAgent-&gt;new;  # we create a global UserAgent object
$ua-&gt;agent("LWP::Simple/$VERSION ");
$ua-&gt;env_proxy;

sub get ($)
{
    my $response = $ua-&gt;get(shift);
    return $response-&gt;decoded_content if $response-&gt;is_success;
    return undef;
}


sub head ($)
{
    my($url) = @_;
    my $request = HTTP::Request-&gt;new(HEAD =&gt; $url);
    my $response = $ua-&gt;request($request);

    if ($response-&gt;is_success) {
	return $response unless wantarray;
	return (scalar $response-&gt;header('Content-Type'),
		scalar $response-&gt;header('Content-Length'),
		HTTP::Date::str2time($response-&gt;header('Last-Modified')),
		HTTP::Date::str2time($response-&gt;header('Expires')),
		scalar $response-&gt;header('Server'),
	       );
    }
    return;
}


sub getprint ($)
{
    my($url) = @_;
    my $request = HTTP::Request-&gt;new(GET =&gt; $url);
    local($\) = ""; # ensure standard $OUTPUT_RECORD_SEPARATOR
    my $callback = sub { print $_[0] };
    if ($^O eq "MacOS") {
	$callback = sub { $_[0] =~ s/\015?\012/\n/g; print $_[0] }
    }
    my $response = $ua-&gt;request($request, $callback);
    unless ($response-&gt;is_success) {
	print STDERR $response-&gt;status_line, " &lt;URL:$url&gt;\n";
    }
    $response-&gt;code;
}


sub getstore ($$)
{
    my($url, $file) = @_;
    my $request = HTTP::Request-&gt;new(GET =&gt; $url);
    my $response = $ua-&gt;request($request, $file);

    $response-&gt;code;
}


sub mirror ($$)
{
    my($url, $file) = @_;
    my $response = $ua-&gt;mirror($url, $file);
    $response-&gt;code;
}


1;

__END__

=pod

=head1 NAME

LWP::Simple - simple procedural interface to LWP

=head1 SYNOPSIS

 perl -MLWP::Simple -e 'getprint "http://www.sn.no"'

 use LWP::Simple;
 $content = get("http://www.sn.no/");
 die "Couldn't get it!" unless defined $content;

 if (mirror("http://www.sn.no/", "foo") == RC_NOT_MODIFIED) {
     ...
 }

 if (is_success(getprint("http://www.sn.no/"))) {
     ...
 }

=head1 DESCRIPTION

This module is meant for people who want a simplified view of the
libwww-perl library.  It should also be suitable for one-liners.  If
you need more control or access to the header fields in the requests
sent and responses received, then you should use the full object-oriented
interface provided by the L&lt;LWP::UserAgent&gt; module.

The module will also export the L&lt;LWP::UserAgent&gt; object as C&lt;$ua&gt; if you
ask for it explicitly.

The user agent created by this module will identify itself as
C&lt;LWP::Simple/#.##&gt;
and will initialize its proxy defaults from the environment (by
calling C&lt;&lt; $ua-&gt;env_proxy &gt;&gt;).

=head1 FUNCTIONS

The following functions are provided (and exported) by this module:

=head2 get

    my $res = get($url);

The get() function will fetch the document identified by the given URL
and return it.  It returns C&lt;undef&gt; if it fails.  The C&lt;$url&gt; argument can
be either a string or a reference to a L&lt;URI&gt; object.

You will not be able to examine the response code or response headers
(like C&lt;Content-Type&gt;) when you are accessing the web using this
function.  If you need that information you should use the full OO
interface (see L&lt;LWP::UserAgent&gt;).

=head2 head

    my $res = head($url);

Get document headers. Returns the following 5 values if successful:
($content_type, $document_length, $modified_time, $expires, $server)

Returns an empty list if it fails.  In scalar context returns TRUE if
successful.

=head2 getprint

    my $code = getprint($url);

Get and print a document identified by a URL. The document is printed
to the selected default filehandle for output (normally STDOUT) as
data is received from the network.  If the request fails, then the
status code and message are printed on STDERR.  The return value is
the HTTP response code.

=head2 getstore

    my $code = getstore($url, $file)
    my $code = getstore($url, $filehandle)

Gets a document identified by a URL and stores it in the file. The
return value is the HTTP response code.
You may also pass a writeable filehandle or similar,
such as a L&lt;File::Temp&gt; object.

=head2 mirror

    my $code = mirror($url, $file);

Get and store a document identified by a URL, using
I&lt;If-modified-since&gt;, and checking the I&lt;Content-Length&gt;.  Returns
the HTTP response code.

=head1 STATUS CONSTANTS

This module also exports the L&lt;HTTP::Status&gt; constants and procedures.
You can use them when you check the response code from L&lt;LWP::Simple/getprint&gt;,
L&lt;LWP::Simple/getstore&gt; or L&lt;LWP::Simple/mirror&gt;.  The constants are:

   RC_CONTINUE
   RC_SWITCHING_PROTOCOLS
   RC_OK
   RC_CREATED
   RC_ACCEPTED
   RC_NON_AUTHORITATIVE_INFORMATION
   RC_NO_CONTENT
   RC_RESET_CONTENT
   RC_PARTIAL_CONTENT
   RC_MULTIPLE_CHOICES
   RC_MOVED_PERMANENTLY
   RC_MOVED_TEMPORARILY
   RC_SEE_OTHER
   RC_NOT_MODIFIED
   RC_USE_PROXY
   RC_BAD_REQUEST
   RC_UNAUTHORIZED
   RC_PAYMENT_REQUIRED
   RC_FORBIDDEN
   RC_NOT_FOUND
   RC_METHOD_NOT_ALLOWED
   RC_NOT_ACCEPTABLE
   RC_PROXY_AUTHENTICATION_REQUIRED
   RC_REQUEST_TIMEOUT
   RC_CONFLICT
   RC_GONE
   RC_LENGTH_REQUIRED
   RC_PRECONDITION_FAILED
   RC_REQUEST_ENTITY_TOO_LARGE
   RC_REQUEST_URI_TOO_LARGE
   RC_UNSUPPORTED_MEDIA_TYPE
   RC_INTERNAL_SERVER_ERROR
   RC_NOT_IMPLEMENTED
   RC_BAD_GATEWAY
   RC_SERVICE_UNAVAILABLE
   RC_GATEWAY_TIMEOUT
   RC_HTTP_VERSION_NOT_SUPPORTED

=head1 CLASSIFICATION FUNCTIONS

The L&lt;HTTP::Status&gt; classification functions are:

=head2 is_success

    my $bool = is_success($rc);

True if response code indicated a successful request.

=head2 is_error

    my $bool = is_error($rc)

True if response code indicated that an error occurred.

=head1 CAVEAT

Note that if you are using both LWP::Simple and the very popular L&lt;CGI&gt;
module, you may be importing a C&lt;head&gt; function from each module,
producing a warning like C&lt;Prototype mismatch: sub main::head ($) vs none&gt;.
Get around this problem by just not importing LWP::Simple's
C&lt;head&gt; function, like so:

        use LWP::Simple qw(!head);
        use CGI qw(:standard);  # then only CGI.pm defines a head()

Then if you do need LWP::Simple's C&lt;head&gt; function, you can just call
it as C&lt;LWP::Simple::head($url)&gt;.

=head1 SEE ALSO

L&lt;LWP&gt;, L&lt;lwpcook&gt;, L&lt;LWP::UserAgent&gt;, L&lt;HTTP::Status&gt;, L&lt;lwp-request&gt;,
L&lt;lwp-mirror&gt;

=cut
</pre></body></html>